Financial Calendar Table

Financial Calendar

Starting - 1st April

Ending - 31st March

Dim - FY Dates = 

GENERATE (

CALENDAR(DATE(2019,4,1),DATE(2026,3,31)),

VAR currentDay = [Date]
VAR daynum = DAY( currentDay )
VAR dayname = FORMAT([Date],"dddd")
VAR Weekdaynum = WEEKDAY([Date],2)
VAR monthnum = MONTH ( currentDay )
VAR yearnum = YEAR ( currentDay )
VAR monthname = FORMAT([Date],"mmmm")
VAR week = IF((WEEKNUM([Date],2))<10,"Week 0" & WEEKNUM([Date],2),"Week " & WEEKNUM([Date],2))
VAR weekofmonth = SWITCH(    TRUE(),    DAY([Date]) <= 7, "Week 1",    DAY([Date]) <= 14, "Week 2",    DAY([Date]) <= 21, "Week 3",    DAY([Date]) <= 28, "Week 4",    "Week 5")
VAR qtr = "Qtr " & QUARTER([Date])
VAR yearmonthnumber = YEAR([Date]) * 100 + MONTH([Date])
VAR yearquarternumber = YEAR([Date]) * 100 + QUARTER([Date])
VAR yearmonthdatenumber = YEAR([Date]) * 10000 + MONTH([Date])*100 + day ( [Date] )
VAR mmmyy = LEFT(monthname, 3) & " " & RIGHT(yearnum, 2)
VAR qqyy = LEFT(qtr, 5) & " " & RIGHT(yearnum, 2)

VAR finyear = IF(MONTH([Date]) <= 3, YEAR([Date]) , YEAR([Date]) +1)
VAR fy = RIGHT((finyear - 1), 2) & "-" & RIGHT(finyear, 2)
VAR finmonthname = FORMAT([Date],"mmmm")
VAR finmonthnum =     IF ( MONTH([Date]) <= 3, MONTH([Date]) + 9, MONTH([Date]) - 3  )
VAR fyqtr = IF(finmonthnum IN {1, 2, 3}, "Qtr 1", IF( finmonthnum IN {4, 5, 6}, "Qtr 2", IF(finmonthnum IN {7, 8, 9}, "Qtr 3", IF(finmonthnum IN {10, 11, 12}, "Qtr 4" ))))
VAR fyyearmonthnumer = finyear * 100 + finmonthnum
VAR FiscalStart = DATE( yearnum - IF(monthnum < 4, 1, 0), 4, 1)
VAR finWeekNum = DATEDIFF(FiscalStart, [Date], WEEK) + 1
VAR fyweek = "Week " & finWeekNum


RETURN ROW (

"Day", daynum,
"Day Name", dayname,
"Week_Day_Num", Weekdaynum,
"Month Number", monthnum,
"Month", monthname,
"Week" , week,
"Week of Month", weekofmonth,
"Quarter" , qtr,
"Year", yearnum,
"Year Month Number", yearmonthnumber,
"Year Quarter Number", yearquarternumber,
"Yearmthdt", Yearmonthdatenumber,
"MMMYY",mmmyy,
"QQYY",qqyy,
"Financial Year", finyear,
"FY", fy,
"Financial Month",finmonthname,
"Financial Month Number", finmonthnum,
"FY Quarter", fyqtr,
"FY YearMonth", fyyearmonthnumer,
"FY Week Number", finWeekNum,
"FY Week", fyweek

)
)

You can simply copy and paste this whole formula above in a new DAX Table.